Cara Membuka dan Membaca Data Excel dengan ListView di VB6

Cara Membuka dan Membaca File Data Excel dengan ListView VB6 - Pada pertemuan kali ini tip dan trik Visual Basic akan membagikan sebuah trik bagaimana Cara Membuka dan Membaca File Data Excel dengan ListView VB6. Microsoft Excel adalah sebuah program dari Microsoft Office yang mempunyai fungsi pengolah database layaknya pada Visual Basic 6.0 berupa perhitungan atau grafik. Microsoft Excel ini memiliki banyak fungsi dan kegunaan diantaranya yaitu 
  • Untuk membuat laporan keuangan akuntansi.
  • Untuk keperluan administrasi sebuah instansi.
  • Untuk mengurutkan beragam data baik pengolah angka maupun kata.
  • Untuk melakukan perhitungan otomatis dengan menggunakan rumus dan logika.

Tahukah Anda di Visual Basic 6.0 pun Anda bisa menampilkan Data yang ada di Excel yang Anda sudah buat baik sebelum atau sudah Anda membuat Data di Excel dengan Syarat Data Excel tersebut harus dijadikan satu folder dengan form Visual Basic yang akan Anda ingin tampilkan di form.

Bagi Anda yang penasaran bagaimana cara menampilkan/membaca Data Excel dengan menggunakan Form yang ada di Visual Basic 6 dengan ListView. Berikut adalah langkah-langkahnya:


  • Buka Form VB6 standar Anda
  • Tambahkan kontrol Microsoft Common Dialog Control dan Microsoft Windows Common Controls 6.0 (SP6) kedalam toolbox
  • Tambahkan CommonDialogControls, 2 Label, 2 CommandButton, 1 ListView dan 1 Frame (optional) kedalam
Atur properti masing-masing sebagai berikut:

Objek
Properti
Nilai
Form1Name
Caption
frmReadExcel
Membaca Data Excel
Label1Name
Caption
Label1
File Data Excel
Label2Name
Caption
lblFileExcel
(kosongkan)
CommandButton1Name
Caption
cmdExcel
......
CommandButton2Name
Caption
cmdReadExcel
Buka Data Excel
ListView1NamelsvData
Frame1NamefraKodiing


  • Desainlah form seperti gambar dibawah ini:

Cara Membuka dan Membaca Data Excel dengan ListView di VB6
Form Desain


  • Selanjutnya tinggalkan dulu Visual Basic Anda (jangan ditutup), sekarang Buka program Excel Anda dan buat Database dengan atribut sebagai berikut :

Kode Barang
Nama Barang
Satuan
Stok
Harga Jual


  • Kemudian isi masing masing kolom dengan data terserah Anda
  • Setelah selesai mengisi data di Excel kemudian Simpan Data Excel Anda dengan nama file StokBarang.Jangan lupa simpan Data Excel Anda satu folder dengan form Visual Basic yang  ingin Anda tampilkan kedalam form
  • Setelah semuanya selesai sekarang buka jendela kode dengan F7, lalu ketik kode dibawah ini:


Listing Program :

Option Explicit
Private Const SW_SHOWNORMAL = 1
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
    ByVal hWnd As Long, _
    ByVal lpOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) As Long
Dim lngRet As Long
'Membaca Data Excel

Private Sub ReadFileExcel()
    Dim oData As ListItem
    Dim Excel As New Excel.Application
    Dim nRow As Integer
    Dim nColKodeBarang As Integer
    Dim nColNamaBarang As Integer
    Dim nColSatuan As Integer
    Dim nColStok As Integer
    Dim nColHargaJual As Integer
    Me.MousePointer = vbHourglass

   'sesuaikan dibawah ini dengan atribut di excel  
    nColKodeBarang = 1
    nColNamaBarang = 2
    nColSatuan = 3
    nColStok = 4
    nColHargaJual = 5
    On Error GoTo ProsesError
    Excel.Workbooks.Open lblFileExcel.Caption, False, True
    lsvData.ListItems.Clear
    For nRow = 2 To 1000
        If Excel.Cells(nRow, nColKodeBarang) <> "" Then
           Set oData = lsvData.ListItems.Add
           oData.Text = Trim(Str(nRow - 1))
           oData.SubItems(nColKodeBarang) = Trim(Excel.Cells(nRow, nColKodeBarang))
           oData.SubItems(nColNamaBarang) = Trim(Excel.Cells(nRow, nColNamaBarang))
           oData.SubItems(nColSatuan) = Trim(Excel.Cells(nRow, nColSatuan))
           oData.SubItems(nColStok) = Format(Val(Excel.Cells(nRow, nColStok)), "###,##0")
           oData.SubItems(nColHargaJual) = Format(Val(Excel.Cells(nRow, nColHargaJual)), "###,##0")
        Else
            Exit For
        End If
    Next
    Excel.Workbooks.Close
    Excel.Quit
    Me.Refresh
    Me.MousePointer = vbDefault
    Set Excel = Nothing
    Exit Sub

ProsesError:
    MsgBox Err.Description, vbExclamation, "Peringatan"
    Excel.Workbooks.Close
    Excel.Quit
    Me.Refresh
    Me.MousePointer = vbDefault
    Set Excel = Nothing
End Sub

'Click Cari File Excel
Private Sub cmdExcel_Click()
    On Error Resume Next
    Dialog.InitDir = App.Path
    Dialog.Filter = " Report File | *.XLS"
    Dialog.ShowOpen
    If Trim(Dialog.FileName) <> "" Then
        lblFileExcel.Caption = Dialog.FileName
    End If
    On Error GoTo 0
End Sub

'Membaca Data File Excel
Private Sub cmdReadExcel_Click()
    ReadFileExcel
End Sub

Private Sub lblFacebook_Click()
    lngRet = ShellExecute(0, vbNullString, "http://401xd.org", vbNullString, "C:\", SW_SHOWNORMAL)
End Sub

Private Sub lblKodiing_Click()
    lngRet = ShellExecute(0, vbNullString, "http://401xd.org", vbNullString, "C:\", SW_SHOWNORMAL)
End Sub

Private Sub lblKontak_Click()
    lngRet = ShellExecute(0, vbNullString, "http://401xd.org", vbNullString, "C:\", SW_SHOWNORMAL)
End Sub

Demikian tips tantang bagaimana Cara Membuka dan Membaca File Data Excel dengan ListView VB6.Semoga bermanfaat, selamat mencoba semoga berhasil

Silahkan komentar pada kolom dibawah ini jika ada yang ingin ditanyakan tentang Cara Membuka dan Membaca Data Excel dengan ListView di VB6.

2 Responses to "Cara Membuka dan Membaca Data Excel dengan ListView di VB6"

  1. Gan kalau edit data lewat listview bagaimana?

    Saya bisa menampilkan listview dan saat baris d klik muncul di textbok kemudian saya edit lewat texbok tersebut.. tapi kendalanya datanya berubah tapi tidak mau langsung muncul di listviewnya hasil perubahannya.. bagaimana agar langsung muncul hasil perubahannya gan tanpa perlu menutup dulu liatviewnya

    ReplyDelete
    Replies
    1. tambah kan perintah refresh di koding lisview, texbox, dan tombol perintah yang digunakan untuk memunculkan data pada listview (jika ada)

      Delete